@echo off
:: ==== Check for Admin rights - Start ====
echo Administrative permissions required. Detecting permissions...

net session >nul 2>&1
if %errorLevel% == 0 (
    echo Success: Administrative permissions confirmed.
) else (
    echo Failure: Insufficient permissions. Please run the .bat file as an Administrator
    pause >nul
    GOTO:EOF
)
:: ==== Check for Admin rights - End ====

:: ==== Set default Values - Start ====
set "appFolderName=1125462_1618409400"
set "appPath=\\Mac\Home\repoFolder"
set "watchFolder=dist"
:: ==== Set default Values - End  ====

:: ==== Open Windows explorer to the zip path ====
start %windir%\explorer.exe "%AppData%\..\Local\Packages\VayenSolutionsGmbH.PitcherImpact_gn2m1gvee0bfr\LocalState\zip"
:: ==== Open Windows explorer to the zip path - End ====

:: ==== Inputs - Start ====
echo:
set /p appFolderName="Enter the app folder name that starts with the fileId (default %appFolderName%):"
echo app folder name: %appFolderName%
echo:
echo:
set /p appPath="Enter the MacOS repo folder path (default %appPath%):"
echo app folder path: %appPath%
echo:
echo:
set /p watchFolder="Enter the watch folder name (default %watchFolder%):"
echo app watch folder name: %watchFolder%
echo:
echo:
:: ==== Inputs - End ====
cd %USERPROFILE%\AppData\Local\Packages\VayenSolutionsGmbH.PitcherImpact_gn2m1gvee0bfr\LocalState\zip
:: ==== Create app symbolik link - Start ====
if exist %appFolderName% ( 
    rmdir /s /q %appFolderName%
    echo:
    echo The folder below already existed and deleted:
    echo %USERPROFILE%\AppData\Local\Packages\VayenSolutionsGmbH.PitcherImpact_gn2m1gvee0bfr\LocalState\zip\%appFolderName%
    echo:
)
echo:
echo Folder created:
echo %USERPROFILE%\AppData\Local\Packages\VayenSolutionsGmbH.PitcherImpact_gn2m1gvee0bfr\LocalState\zip\%appFolderName%
mklink /D %appFolderName% %appPath%\%watchFolder%
echo:
:: ==== Create app symbolik link - End ====
echo:
echo Next step
echo Run your Windows watch script found in package.json (e.g npm run watch) on the %appFolderName% repo
echo:
pause